Détection des collisions en Flash

31/07/2005

Par Stephane Eyskens (Autres articles)
 

Détection des collisions en Flash et cadre d'utilisation

 							
mc1.xMin=mc1._x;
mc1.xMax=mc1._x+300;
mc1.yMin=mc1._y-150;
mc1.yMax=mc1._y+150;
mc1.onEnterFrame=function()
{
	//On détecte quelle si l'une des flèches est enfonçée et on fait bouger le cercle
	//si celui-ci est dans les limites _x _y autorisées.
	if(Key.isDown(Key.RIGHT) && this._x<this.xMax)
	{
		this._x+=10;
	}

	if(Key.isDown(Key.LEFT) && this._x>this.xMin)
	{
		this._x-=10;
	}
	if(Key.isDown(Key.UP) && this._y>this.yMin)
	{
		this._y-=10;
	}
	if(Key.isDown(Key.DOWN) && this._y<this.yMax)
	{
		this._y+=10;
	}
}

mc2.onEnterFrame=function()
{
	Collision.text="";
	//hitTest permet de détecter si un clip "clip" est entré en collision avec le clip
	//courant. Dans ce cas, nous testons si mc1 est entré en collision avec "this" c'est à dire mc2.
	if(mc1.hitTest(this))
	{
		Collision.text="Collision détectée";
	}
}

• Les flèches du clavier
• La barre d'espace
• L'envoi automatique de vaisseaux ennemis
• Détecter si une balle touche un vaisseau ennemi et supprimer celui-ci
• Détecter si un vaisseau ennemi a atteint le bas de l'écran auquel cas, le joueur perd

"commencer" est un bouton qui permet de commencer le jeu
commencer.onPress=function()
{
	gotoAndPlay(2);
}
stop();

//tableau contenant le nom des instances ennemies
ennemi=new Array();
//Compteur pour les balles
fusee.currentItem=0;
//code exécuté en boucle pour la fusée
fusee.onEnterFrame=function()
{
	//Gestion du déplacement gauche-droite
	if(Key.isDown(Key.LEFT))
	{
		this._x-=50;
	}
	if(Key.isDown(Key.RIGHT))
	{
		this._x+=50;
	}
	//La touche espace déclenche un tir
	if(Key.isDown(Key.SPACE))
	{		
	 //On ajoute le clip sur la scène et on le positionne
		_root.attachMovie("bullet","bullet"+this.currentItem,100+this.currentItem);	
		_root["bullet"+this.currentItem]._x=this._x+25;
		_root["bullet"+this.currentItem]._y=this._y-30;
		//En boucle, la balle va vers le haut de l'écran
		//et on regarde si on touche un ennemi
		_root["bullet"+this.currentItem].onEnterFrame=function()
		{
			if(this._y<0) this.removeMovieClip();				
			//Ennemi est un tableau associatif contenant le
			//nom d'instance de tous les ennemis envoyés
			//On parcourt le tableau pour voir si on touche
			//un des ennemis ou non
			for(value in ennemi)
			{
				//hittest détecte la collision
				if(_root[value].hitTest(this))
				{
					//ici, la collision est détectée
					//Suppression du vaisseau ennemi
					_root[value].removeMovieClip();
					//suppression de la clé dans le tab. assoc.
					delete(_root.ennemi[value]);						
					//Suppression de la balle
					this.removeMovieClip();						
				}				
			}
			this._y-=45;
		}
		this.currentItem++;
	}
}
//Ennemis est le MC qui va envoyer les ennemis
//tout au long de l'animation à raison de 1 ennemi par sec.
ennemis.timeStarted=getTimer()/1000;		
ennemis.interval=1;
ennemis.item=1;
ennemis.onEnterFrame=function()
{
	if((getTimer()/1000) > (this.timeStarted+this.interval))
	{
		//si l'intervalle est écoulé, on envoie un nouvel ennemi
		_root.attachMovie("ennemi","ennemi"+this.item,200+this.item);
		//On ajoute la clé dans le tab. assoc.
		_root.ennemi["ennemi"+this.item]=1;		
		_root["ennemi"+this.item]._x=random(300);		
		//En boucle pour l'ennemi
		_root["ennemi"+this.item].onEnterFrame=function()		
		{							
		  //On le fait descendre de 10px
			this._y+=10;			
			//Si _y > 300, on ne l'a pas touché et donc
			//on a perdu
			if(this._y>300)
			{					
				this.removeMovieClip();
				gotoAndStop(3);
			}			
		}		
		this.item+=1;					
		this.interval+=1;
	}
}
stop();

//Suppression des ennemis restant
for (value in ennemi)
{
	_root[value].removeMovieClip();
}
//Code du bouton recommencer
recommencer.onPress=function()
{
	gotoAndPlay(2);
}